home *** CD-ROM | disk | FTP | other *** search
/ MacTech 1 to 12 / MacTech-vol-1-12.toast / Source / MacTech® Magazine / Volume 05 - 1989 / 05.07 Jul 89 / Terminal / SerI⁄O.asm next >
Encoding:
Assembly Source File  |  1989-03-09  |  6.6 KB  |  220 lines  |  [TEXT/EDIT]
  1. ; File: SerI/O.asm
  2. ;----------------------------------------------------------------------
  3. ; SerI/O.asm consists of the following stand-alone serial I/O routines:
  4. ;
  5. ; Function    OpenSerial(Port: integer): OSErr
  6. ; Function    Config(Port, SerVal: integer): OSErr
  7. ; Function    GetSerial(Port: integer, buffer: pointer): CharCnt
  8. ; Function    PutSerial(Port: integer, CharBuf: pointer, count: longint): OSErr
  9. ; Function    SetBuf(Port: integer, BufSiz: long): OSErr
  10. ; 
  11. ; Port refers to the port reference number, which is -6 for the modem 
  12. ; input port (port A) or -8 for printer input port  (port B)
  13. ;
  14. ; For a great description of how to write modular assembly language
  15. ; routines see Dan Weston's "The Complete Book of Macintosh Assembly
  16. ; Language Programming Volume I", Appendix D
  17. ;
  18. ;  1/14/88    Working version of the routines
  19. ;
  20. ; written by Frank Henriquez
  21. ;----------------------------------------------------------------------
  22. ; Register usage:
  23. ; d0: general purpose. 
  24. ; d1, d2, d3, d4, d5, d6, d7 : not used.
  25. ;
  26. ; a0: general purpose, used for buffers and parameter blocks.
  27. ; a1: general purpose.
  28. ; a2, a3, a4: not used.
  29. ; a6: used as the local stack frame pointer
  30. ; a5, a7 : system use. 
  31. ;----------------------------------------------------------------------
  32.  
  33. Include        Traps.D
  34. Include        SysEqu.D
  35.  
  36.     XDEF    OpenSerial
  37.     XDEF    Config
  38.     XDEF    GetSerial
  39.     XDEF    PutSerial
  40.     XDEF    SetBuf 
  41.  
  42. ; equates for each stack frame
  43.  
  44. pBlock        equ    -ioQelSize
  45.  
  46. OpenPar        equ     2        ; OpenSerial - # of parameter words on stack
  47. OpenRes        equ    10        ; OpenSerial - offset to result word
  48. OpenPort    equ     8        ; OpenSerial - offset to Port Reference #
  49.  
  50. ConfPar        equ     4        ; Config - # of parameter words on stack
  51. ConfRes        equ    12        ; Config - offset to result word
  52. ConfPort    equ    10        ; Config - offset to port Reference #
  53. ConfVal        equ     8        ; Config - offset to port config value
  54.  
  55. GetPar        equ     6        ; you've probably figured the pattern
  56. GetCnt        equ    14        ; offset to character count
  57. GetPort        equ    12        ; out by now...
  58. GetBuf        equ     8         ; offset to character buffer pointer
  59.  
  60. PutPar        equ    10
  61. PutPort        equ    16
  62. PutBuf        equ    12        ; offset to character buffer pointer
  63. PutCnt        equ     8        ; offset to character count pointer
  64. PutRes        equ    18        ; dummy result 
  65.  
  66. SetPar        equ     6
  67. SetRes        equ    14        ; offset to SetBuf result word
  68. SetPort        equ    12
  69. SetSiz        equ     8        ; offset to new buffer size
  70.  
  71. ; misc. equates
  72.  
  73. SerReset    equ     8        ; from Inside Macintosh
  74. SerSetBuf    equ     9        ; from Inside Macintosh
  75. ioNamePtr    equ    18        ; missing from MDS
  76.  
  77.  
  78. ;-------------- OpenSerial ------------------
  79. ; Opens the modem port for reads and writes.
  80. ;
  81. ; Procedure    OpenSerial(Port: integer): OSErr
  82.  
  83. OpenSerial
  84.     link    a6,#pBlock        ; local space for parameter block
  85.     lea    pBlock(a6),a0        ; point to parameter block
  86.     lea    '.AIn',a1        ; assume port A input
  87.     cmpi.w    #-6,OpenPort(a6)    ; open port B if not -6 (port A)
  88.     beq.s    @1
  89.     lea    '.Bin',a1        ; open port B input
  90. @1    bsr.s    Openit
  91.     lea    '.AOut',a1        ; assume port A output
  92.     cmpi.w    #-6,OpenPort(a6)
  93.     beq.s    @2
  94.     lea    '.Bout',a1        ; open port B output
  95. @2    bsr.s    Openit
  96.  
  97. OExit    move.w    d0,OpenRes(a6)        ; procedure returns a 0 if no errors
  98.     _KillIO                ; kill any pending calls
  99.     unlk    a6            ; discard local stack area
  100.     move.l    (sp)+,a0        ; get return address
  101.     addq.l    #OpenPar,sp        ; clean up stack
  102.     jmp    (a0)            ; end of InitSerial
  103.  
  104. Openit    
  105.     move.l    a1,ioNamePtr(a0)    ; tell the Device Manager which
  106.     _Open                ; port to open
  107.     rts
  108.  
  109.  
  110. ;----------- Configure ports --------------
  111. ; Sets the Port to the baud rate, data length,
  112. ; parity, stops, etc. held in SerVal.
  113. ;
  114. ; Procedure    Config(Port, SerVal : integer) : OSErr
  115.  
  116. Config
  117.     link    a6,#pBlock        ; local space for parameter block
  118.     lea    pBlock(a6),a0        ; point to parameter block
  119.     move.w    ConfPort(a6),d0        ; get Input Reference number
  120.     bsr.s    doConf            ; configure the input side
  121.     tst.w    d0            ; check for errors and
  122.     bne.s    CExit            ; exit with the error flag in d0
  123.     move.w    ConfPort(a6),d0        ; get Input Ref number
  124.     subq.w    #1,d0            ; and make it the output ref num
  125.     bsr.s    doConf            ; configure the output side
  126.  
  127.  
  128. CExit    move.w    d0,ConfRes(a6)        ; save result
  129.     unlk    a6
  130.     move.l    (sp)+,a0
  131.     addq.l    #ConfPar,sp        ; and clean up the stack
  132.     jmp    (a0)            ; end of Configure
  133.  
  134. doConf    move.w    d0,ioRefNum(a0)        ; port #
  135.     move.w    #SerReset,csCode(a0)    ; reset port to
  136.     move.w    ConfVal(a6),csParam(a0)    ; these new settings
  137.     _Control
  138.     rts
  139.  
  140.  
  141. ;---------------- SetBuf -------------------
  142. ; increases the size of the Port input buffer
  143. ;
  144. ; SetBuf(Port:Integer, BufSiz:long):OSErr
  145.  
  146. SetBuf    link    a6,#pBlock        ; local space for parameter block
  147.     move.l    SetSiz(a6),d0
  148.     beq.s    @1            ; if size = 0, reset input buffer
  149.     _NewPtr                ; get a nonrelocatable block
  150.     tst.l    d0            ; abort if couldn't get it
  151.     bne    Exit
  152.     move.l    a0,a1            ; save block ptr in a1
  153.     move.l    SetSiz(a6),d0        ; reload the buffer size
  154. @1    lea    pBlock(a6),a0        ; point to parameter block
  155.     move.w    SetPort(a6),ioRefNum(a0)
  156.     move.w    #SerSetBuf,csCode(a0)
  157.     move.l    a1,csParam(a0)         ; pointer to new buffer
  158.     move.w    d0,csParam+4(a0)
  159.     _Control
  160. Exit    move.w    d0,SetRes(a6)
  161.     unlk    a6            ; standard exit routine
  162.     move.l    (sp)+,a0
  163.     addq.l    #SetPar,sp
  164.     jmp    (a0)            ; end of SetBuf
  165.  
  166.  
  167. ;--------------- GetSerial ----------------
  168. ; GetSerial checks the Port to see if any
  169. ; characters have been received, and proceeds
  170. ; to read them into the input buffer.
  171. ; If none have been received, GetSerial returns
  172. ; a 0 in the character count variable.
  173. ;
  174. ; Procedure    GetSerial(Port:integer, buffer:pointer) : CharCnt: long
  175.  
  176. GetSerial
  177.     link    a6,#pBlock
  178.     lea    pBlock(a6),a0
  179.     move.w    GetPort(a6),ioRefNum(a0)
  180.     move.w    #2,csCode(a0)        ; call SerGetBuf
  181.     _Status
  182.     move.l    csParam(a0),d0        ; get # of characters received
  183.     move.l    d0,GetCnt(a6)
  184.     beq.s    @2            ; if none, then leave, if there are
  185.                     ; characters available, read them.
  186. @1    move.w    GetPort(a6),ioRefNum(a0)
  187.     move.l    GetBuf(a6),ioBuffer(a0)    ; the input buffer
  188.     move.l    d0,ioReqCount(a0)    ; read the characters
  189.     _Read
  190. @2    unlk    a6            ; standard exit routine
  191.     move.l    (sp)+,a0
  192.     addq.l    #GetPar,sp        ; leave char count on stack
  193.     jmp    (a0)            ; end of GetSerial
  194.  
  195.  
  196. ;--------------- PutSerial ----------------
  197. ; PutSerial sends the characters in the buffer
  198. ; out the Port. This routine is pretty
  199. ; primitive - it ignores any pending writes
  200. ; and errors, but...it works. It returns a dummy result.
  201. ;
  202. ; function    PutSerial(Port:integer, CharBuf:pointer, count: pointer): OSErr
  203.  
  204. PutSerial
  205.     link    a6,#pBlock        ; local space for parameter block
  206.     lea    pBlock(a6),a0        ; point to parameter block
  207.     move.w    PutPort(a6),d0        ; get the port ref #
  208.     subq.w    #1,d0            ; make it the port output ref num
  209.     move.w    d0,ioRefNum(a0)        ; modem output port
  210.     move.l    PutBuf(a6),ioBuffer(a0)    ; point to buffer
  211.     move.l    PutCnt(a6),a1        ; get pointer to char count
  212.     move.l    (a1),ioReqCount(a0)    ; and put char count here
  213.     _Write
  214.     move.w    #0,PutRes(a6)        ; save a 0 as a dummy result
  215.     unlk    a6            ; standard exit routine
  216.     move.l    (sp)+,a0
  217.     adda.l    #PutPar,sp
  218.     jmp    (a0)            ; end of PutSerial
  219.  
  220.